Plots with ROOTs

Follow one question at a time: inspect the data, make a first plot, improve its readability, then choose different charts for different questions. Both editions use the same five published CSV datasets, include crew and work through the same eighteen figures. No local AWK preparation is needed.

Begin with the independent Meet gnuplot chapter below; it needs no CSV files. Chapters 1–11 then apply the tool to counts, percentages and composition. Chapters 12–17 are chart extensions: choose them to answer a question, not because every option must be learned on the first day.

The workflow follows the ROOT principles: Robust, Open, Ongoing, Time-tested. Keep the data, plotting instructions and resulting figures understandable. Change one setting at a time and compare the result.

Use gnuplot 6.0 or newer with SVG and PNG output, and curl for downloads. Retrieve the data before an offline lesson. Once the downloads are available, all plotting can run without further network access.

This chapter needs only gnuplot. No Titanic files, shared style or network connection is used. Start with a function; then use one small synthetic table. The short continuations below change one thing at a time. Predict the change, run it and look at the plot before proceeding.

We now apply the plotting commands we already know to a real dataset. The introduction supplied the tool; from here on we ask questions about people, groups and survival. The new step in this chapter is retrieving and interpreting published columns, not calculating a new dataset.

Use Titanic Passengers and Crew: Demographics and Survival Data, version 1.0.1. This version-specific record fixes which data the lesson uses. All counting and age grouping have already been done; no conversion or preprocessing is needed.

The person-level columns are class, sex, age, survived and embarked. There are 2,207 records: 1,317 passengers and 890 crew, with 711 survivors. The categories 1st, 2nd, 3rd and Crew appear in that order. Crew is a separate group, not a fourth passenger class.

NA marks missing values, not zero. The two unknown ages are excluded from age summaries, leaving 2,205 people. The dataset description documents its provenance, transformations and limitations; these are descriptive records, not evidence of causal effects.

Start with everyone aboard by class and crew. Each table row is one category and its aboard count supplies the bar height. Keep gnuplot's default appearance for this first experiment; later topics make each design choice explicit.

In your editor, create plots/by_class_aboard.gp inside terminal/. Enter listing 28 and save it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,300 font 'sans,13'
set output 'figures/by_class_aboard.svg'
set style data histograms
set yrange [0:*]
plot data using 2:xtic(1) title "Aboard"
unset output

After saving, run listing 29 from Bash in terminal/.

gnuplot -d plots/by_class_aboard.gp

Practice this topic in Challenge 3: Ask the first plot a different question.

Open figures/by_class_aboard.svg in a browser. set output names that file. Use a plain-text editor, save with the exact .gp extension—not =.gp.txt=— then rerun and reload the browser after each change.

Bash receives the gnuplot -d ... command; the editor contains gnuplot statements. The -d flag skips personal startup files. reset clears settings left by earlier plots. Relative paths are resolved from the working directory, not from the script: stay in terminal/.

You can also work at the gnuplot prompt. Run listing 30 now, then use load after saving a script. Bash's $ and gnuplot's gnuplot> prompts are not characters to copy into commands.

$ gnuplot -d

For a text preview without a separate window, enter listing 31 at that prompt. load first runs the script and saves its SVG; switching to dumb afterwards and calling replot also draws the chart in the terminal. The saved SVG remains unchanged. Text output has limited resolution and cannot faithfully reproduce every later chart, especially multiplots and colour heatmaps. Use their saved SVG or PNG files for the full result.

gnuplot> load 'plots/by_class_aboard.gp'
gnuplot> unset output
gnuplot> set terminal dumb size 79,24
gnuplot> replot

New here: categorical positions and boxes, rather than the numeric x coordinates and points in the introduction. using 3:xtic(1) takes values from column 3 and category labels from column 1. This version shows only survivors. notitle suppresses an unhelpful data-source legend. The zero baseline is explicit; descriptive wording is the next refinement.

Category labels versus numerical coordinates. xtic(1) supplies labels, not numerical x positions: the classes are spaced equally by row. For age data, use the actual age as x, for example using 1:2 when column 1 holds age and column 2 holds the measured value. Ages 1, 4 and 10 must have gaps of 3 and 6 years; plotting against row number would make both gaps equal.

In your editor, create plots/by_class_survivors.gp inside terminal/. Enter listing 32, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_survivors.svg'
set boxwidth .5 relative
set yrange [0:*]
plot data using 3:xtic(1) with boxes notitle
unset output

Run listing 33 from Bash in terminal/.

gnuplot -d plots/by_class_survivors.gp

Practice this topic in Challenge 4: Give bars an honest baseline.

New here: histograms groups bars by category. Both outcomes share axes and a legend. The comma and series title work just as they did for the two synthetic series in the introduction. We repeat data for clarity; later '' means reuse the preceding data source. Colours are still gnuplot's defaults.

In your editor, create plots/by_class_counts.gp inside terminal/. Enter listing 34, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_outcomes.svg'
set style data histograms
set style fill solid 1.0
set title "Titanic: survivors and deaths by class and crew"
set ylabel "People aboard"
set yrange [0:*]
set key top left
plot data using 3:xtic(1) title "Survived", \
     data using 4         title "Died"
unset output

Run listing 35 from Bash in terminal/.

gnuplot -d plots/by_class_counts.gp

Practice this topic in Challenge 5: Check two series against their total.

Every visual choice is explicit: left and bottom axes only (set border 3), outward ticks, light horizontal guides and two colours chosen on purpose. Use a strong colour for survivors and a quiet one for deaths. In a report, the caption can carry the title rather than repeating it inside the figure.

In your editor, create plots/by_class_styled.gp inside terminal/. Enter listing 36, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_outcomes_styled.svg'
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
set border 3 lw 1.9
set tics out nomirror scale 0.9
set grid ytics lc rgb "#d5d8dc" lw .5
set key top left
set linetype 1 lc rgb "#14507d"
set linetype 2 lc rgb "#aab0b8"
set style fill solid 0.9 border -2
set style data histograms
set style histogram clustered gap 1
set boxwidth 0.9

set ylabel "People aboard"
set xlabel "Passenger class or crew"
set yrange [0:*]
plot data using 3:xtic(1) title "Survived", \
     data using 4         title "Died"
unset output

Run listing 37 from Bash in terminal/.

gnuplot -d plots/by_class_styled.gp

Most of the setup describes a visual style, not this particular question. Repeating those settings in every plot invites inconsistent edits.

Practice this topic in Challenge 6: Make one visual change at a time.

This recreates the deliberately styled grouped plot. Its appearance should match the previous figure apart from the x-axis label: the style has moved, not the question. Each plot now contains primarily what is specific to its data and comparison.

In your editor, create plots/by_class_shared.gp inside terminal/. Enter listing 39, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_outcomes_shared_style.svg'
load 'style.gp'
set ylabel "People aboard"
set yrange [0:*]
plot data using 3:xtic(1) title "Survived", \
     ''   using 4         title "Died"
unset output

Run listing 40 from Bash in terminal/.

gnuplot -d plots/by_class_shared.gp

Practice this topic in Challenge 7: Change a shared setting once.

rowstacked puts survivors and deaths on top of each other. The total height of each bar is the size of the group, so this chart answers both “how large was the group?” and “how did its outcomes divide?”

In your editor, create plots/by_class_stacked.gp inside terminal/. Enter listing 41, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_outcomes_stacked.svg'
load 'style.gp'
set style histogram rowstacked
set ylabel "People aboard"
set yrange [0:*]
plot data using 3:xtic(1) title "Survived", \
     ''   using 4         title "Died"
unset output

Run listing 42 from Bash in terminal/.

gnuplot -d plots/by_class_stacked.gp

The bar totals are 324, 284 and 709 passengers, followed by 890 crew. Crew is the largest group, with 679 deaths; third class has 528 deaths. Both groups are larger than either first or second class.

Practice this topic in Challenge 8: Choose between stacked and grouped counts.

The same stacks are now scaled to 100 per cent. A computed column is an expression in parentheses; $3 means “column 3 of this row”. Survived divided by aboard, multiplied by 100, is the survival percentage. The survivors' and deaths' percentages add to 100 within each group.

Keep the expression in parentheses: ($3/$2*100) is a calculation, whereas an unparenthesised using entry is interpreted as a column specification.

In your editor, create plots/by_class_shares.gp inside terminal/. Enter listing 43, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_outcome_percentages.svg'
load 'style.gp'
set style histogram rowstacked
set ylabel "Share of each class"
set yrange [0:100]
set format y "%.0f%%"
set key below
plot data using ($3/$2*100):xtic(1) title "Survived", \
     ''   using ($4/$2*100)         title "Died"
unset output

Run listing 44 from Bash in terminal/.

gnuplot -d plots/by_class_shares.gp

Practice this topic in Challenge 9: Distinguish a share from a count.

New here: one rate per group, followed by an optional text layer. The denominator is still the aboard count of that same class or Crew group, not the total of 2,207. First draw the bars without formatting strings.

Compare women's and men's survival rates within each group. Women use columns 3/2; men use 6/5. Each denominator must be that group's own aboard count, not the total number of survivors or the total aboard.

The colours now encode sex rather than survival outcome. A linetype number only selects a style: change its colour and the legend together when the plot's question changes. These categories include children.

In your editor, create plots/by_class_and_sex.gp inside terminal/. Enter listing 48, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
sex = 'data/titanic_by_sex.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_and_sex_survival_rates.svg'
load 'style.gp'
set linetype 1 lc rgb "#14507d"   # women
set linetype 2 lc rgb "#c47a2c"   # men
set ylabel "Survived"
set yrange [0:100]
set format y "%.0f%%"
set key top right
plot sex using ($3/$2*100):xtic(1) title "Women", \
     sex using ($6/$5*100)         title "Men"
unset output

Run listing 49 from Bash in terminal/.

gnuplot -d plots/by_class_and_sex.gp

Practice this topic in Challenge 11: Compare within a group.

A pie shows one whole divided into parts. Here the whole is everyone aboard, including crew. Use it for one composition; bars are clearer for comparing survival rates between groups.

For a simple pie, with circles is sufficient in gnuplot 6: supply the centre, radius, start angle and end angle for each slice, plus its colour. The default set style circle wedge connects the arc to the centre. No polar mode is needed. The donut chapter introduces with sectors for actual ring segments; using gnuplot 6 does not mean replacing every older style.

New here: stats data using 2 nooutput reads the aboard column and stores its sum as STATS_sum. Save that as total (2,207). The named function angle_for_count converts a count into its share of 360 degrees. For example, first class occupies 324/2207*360, about 52.85 degrees. The running variable angle_end carries one slice's end to the next slice's start. Start with slices only: labels are an extension in Challenge 12.

In your editor, create plots/by_class_pie.gp inside terminal/. Enter listing 50, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 900,400 font 'sans,13'
set output 'figures/by_class_aboard_pie.svg'
# reset leaves Cartesian coordinates and unrestricted ranges for stats.
stats data using 2 nooutput
total = STATS_sum
angle_for_count(people) = people * 360.0 / total

set title "Titanic: people aboard by class and crew"
set angles degrees
unset border
unset tics
unset grid
unset key
set size ratio -1
set xrange [-1.05:1.05]
set yrange [-1.05:1.05]
set style fill solid 1.0 border lc rgb "white"
# circles: x : y : radius : start angle : end angle : color
angle_end = 0
plot data using (0):(0):(1):(angle_end): \
     (angle_end = angle_end + angle_for_count($2)):($0 + 1) \
     with circles linecolor variable notitle
unset output

Run listing 51 from Bash in terminal/.

gnuplot -d plots/by_class_pie.gp

This example starts with reset, so stats runs before restrictive ranges or polar mode are enabled. For a pasted fragment in an existing session, run unset polar and set autoscale before stats.

Read the last line of the calculation from left to right: the fourth circle column reads the old angle_end; the fifth adds this row's angular width and returns the new end. This single update is necessary to join successive slices. Before repeating the plot, reset angle_end to zero; plain replot alone would reuse the accumulated value. The sixth column selects a distinct default colour via linecolor variable. ($0 + 1) turns row indices 0–3 into colour indices 1–4. The explicit ranges leave room around the unit circle, avoid the empty-y-range warning and prevent clipping artefacts at the circle's boundary. The equal axis scale (set size ratio -1) keeps the pie circular, not elliptical.

A dumbbell connects the men's survival rate to the women's rate for each class or crew group. The line's length is their gap.

New here: horizontal displacement between two already familiar rates. As in the rate example, survival_percent names the repeated arithmetic. Column 3 divided by 2 is the women's rate; column 6 divided by 5 is the men's rate. Subtracting them gives percentage points, not percent change. The colours and larger points below are the report layer, not new data.

with vectors takes x:y:dx:dy: a starting point and a displacement. Start at the men's rate, use the difference between the rates as dx, and keep dy at zero. nohead removes the arrowhead to leave a connecting line.

In your editor, create plots/by_class_sex_gap.gp inside terminal/. Enter listing 59, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
sex = 'data/titanic_by_sex.csv'
set terminal svg size 820,400 font 'sans,14'
set output 'figures/by_class_and_sex_survival_gap.svg'
load 'style.gp'
survival_percent(survived, aboard) = 100.0 * survived / aboard
unset grid
set grid xtics lc rgb "#d5d8dc" lw 0.8
set xrange [0:100]
set yrange [3.6:-0.6]
set format x "%.0f%%"
set xlabel "Survived"
set ytics scale 0
set key above
set linetype 1 lc rgb "#14507d"   # women
set linetype 2 lc rgb "#c47a2c"   # men

plot sex using (survival_percent($6,$5)):0:(survival_percent($3,$2) - survival_percent($6,$5)):(0):ytic(1) \
         with vectors nohead lw 4 lc rgb "#d5d8dc" notitle, \
     ''  using (survival_percent($3,$2)):0 with points pt 7 ps 2 lc 1 title "Women", \
     ''  using (survival_percent($6,$5)):0 with points pt 7 ps 2 lc 2 title "Men"
unset output

Run listing 60 from Bash in terminal/.

gnuplot -d plots/by_class_sex_gap.gp

Practice this topic in Challenge 16: Add an honest name for the gap.

A spider or radar plot shows several measures of one thing at once: one axis per measure, one polygon per row. Each class or crew group is a polygon across five percentages derived from the class-and-sex counts. This course uses gnuplot 6.0 or newer, including for spider plots.

Each plot clause adds an axis. All axes run from 0 to 100, and set paxis ... label supplies each spoke label and its rotation.

In your editor, create plots/by_class_profile.gp inside terminal/. Enter listing 61, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
sex = 'data/titanic_by_sex.csv'
set terminal svg size 820,640 font 'sans,14'
set output 'figures/by_class_profile_spider.svg'
load 'style.gp'

  set title "Titanic survival by class and sex" offset 0,1 font ",18"
  unset border; unset tics; unset grid
  set spiderplot

  # One axis per plot clause below: five measures, all in per cent
  set for [p=1:5] paxis p range [0:100]
  set paxis 1 tics 0,25,100 format "%.0f%%"
  set for [p=2:5] paxis p tics format ""

  # Spoke labels, each at right angles to its spoke. Spoke p points at
  # 90 - (p-1)*72 degrees; the label is turned 90 degrees less than that,
  # and turned over by 180 where it would otherwise stand upside down.
  set paxis 1 label "All survived"   rotate by   0
  set paxis 2 label "Women survived" rotate by -72
  set paxis 3 label "Men survived"   rotate by  36
  set paxis 4 label "Women aboard"   rotate by -36
  set paxis 5 label "Men aboard"     rotate by  72

  set grid spiderplot lc rgb "#d0d0d0" dt 2 lw 1
  set style spiderplot fs transparent solid 0.18 border lw 2
  set key outside right center

  # One polygon per row of the table, i.e. per class
  set linetype 1 lc rgb "#14507d" lw 3
  set linetype 2 lc rgb "#c47a2c" lw 3
  set linetype 3 lc rgb "#3f8f5a" lw 3
  set linetype 4 lc rgb "#8064a2" lw 3

  # Columns: 2 women aboard, 3 women survived, 5 men aboard, 6 men survived
  # key(1) names each polygon after column 1 (1st, 2nd, 3rd, Crew)
  plot \
       sex using (($3+$6)/($2+$5)*100):key(1) with spiderplot notitle, \
       sex using ($3/$2*100)                  with spiderplot notitle, \
       sex using ($6/$5*100)                  with spiderplot notitle, \
       sex using ($2/($2+$5)*100)             with spiderplot notitle, \
       sex using ($5/($2+$5)*100)             with spiderplot notitle
unset output

Run listing 62 from Bash in terminal/.

gnuplot -d plots/by_class_profile.gp

The last two axes are group composition—the shares of women and men aboard—not survival rates. They sum to 100 and therefore mirror each other. Crew is overwhelmingly male and has the lowest overall survival rate, 23.7%. This describes the group; it does not establish why people survived.

Practice this topic in Challenge 17: Test whether polygon shape is evidence.

The inner ring divides everyone aboard into three passenger classes and crew. The outer ring splits each group into survivors and deaths. It combines the two messages of the stacked counts: group size and outcome.

This is an optional report example, not the next minimal plotting command. New here are ring boundaries and layered angular intervals; the calculations still use the same counts and whole as the pie. Read the inner-ring pass first, then the two outcome passes, and only then the label passes. The stacked chart remains a simpler way to communicate the same quantities.

Draw real ring segments with with sectors: class segments run from hole_radius to split_radius; outcome segments run from split_radius to outer_radius. The centre stays empty without a white covering disc. Each pass resets pos so both rings share the same group boundaries.

Here the sectors columns are start angle:inner radius:angular width:radial width, optionally followed by a colour. Where circles takes start and end angles, sectors takes a start angle and angular width. In polar mode, labels take angle:radius:text directly. See the gnuplot 6 manual, Sectors.

In your editor, create plots/by_class_donut.gp inside terminal/. Enter listing 63, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_class.csv'
set terminal svg size 600,600 font 'sans,11'
set output 'figures/by_class_and_outcome_donut.svg'
load 'style.gp'
unset polar
set autoscale
stats data using 2 nooutput
total = STATS_sum
set angles degrees
ang(n) = n * 360.0 / total

set polar
set theta right ccw
unset raxis
unset border; unset tics; unset grid
set key below horizontal center
set size ratio -1
set xrange [-1.35:1.35]
set yrange [-1.35:1.35]
set rrange [0:1.35]
set style fill solid 1.0 border lc rgb "white"
set linetype 3 lc rgb "#2b3036"
set linetype 4 lc rgb "#4a5058"
set linetype 5 lc rgb "#6c737c"
set linetype 6 lc rgb "#515969"

hole_radius = 0.40
split_radius = 0.72
outer_radius = 1.0
label_radius = (hole_radius + split_radius)/2
rate_radius = 1.16

# sectors: start angle : inner radius : angular width : radial width
# Each outcome pass advances pos by the WHOLE group, not just that outcome.
plot pos = 0, \
     data using (pos):(split_radius): \
          (span = ang($3), pos = pos + ang($2), span): \
          (outer_radius - split_radius) \
          with sectors lc rgb "#14507d" title "Survived", \
     pos = 0, \
     data using (pos + ang($3)):(split_radius): \
          (span = ang($4), pos = pos + ang($2), span): \
          (outer_radius - split_radius) \
          with sectors lc rgb "#dfe3e8" title "Died", \
     pos = 0, \
     data using (pos):(hole_radius): \
          (span = ang($2), pos = pos + span, span): \
          (split_radius - hole_radius):($0 + 3) \
          with sectors lc variable notitle, \
     pos = 0, \
     data using (mid = pos + ang($2)/2, pos = pos + ang($2), mid): \
                (label_radius):(strcol(1)) \
          with labels tc rgb "white" center notitle, \
     pos = 0, \
     data using (mid = pos + ang($2)/2, pos = pos + ang($2), mid): \
                (rate_radius):(sprintf("%.0f%%", 100.0 * $3 / $2)) \
          with labels tc rgb "#2b3036" center notitle
unset output

Run listing 64 from Bash in terminal/.

gnuplot -d plots/by_class_donut.gp

The first pass draws survivors in blue; the second starts after those survivors and fills the remaining group angle in light grey. Both passes advance pos by the whole group's angle, but return only the outcome's angular width. These widths use counts divided by the total aboard, so survivors and deaths together align with the corresponding inner segment. set polar lets the labels use angle:radius:text directly.

The plot uses square output dimensions rather than the wide default. Class names sit inside the inner ring and survival rates outside. Crew is the largest inner wedge, 40.3%, with a mostly grey outer rim. First class is 14.7% of those aboard and has a mostly blue rim.

Change hole_radius to adjust the hole. Keep 0 < hole_radius < split_radius < outer_radius=; the radial widths are differences between these boundaries, not absolute outer radii. label_radius keeps class names halfway across the inner ring.

Practice this topic in Challenge 18: Separate decoration from information.

A sparkline is a chart about the size of a word: no axes, labels or legend, just the data's shape inside a sentence. It answers “what does the trend look like?” without interrupting the reading.

Use titanic_by_age.csv with its 25 three-year groups from 0–2 to 72–74. Both sexes, all classes and crew are included; two unknown ages are excluded. These bars show how many people were in each age group, not how many survived.

In your editor, create plots/by_age_counts.gp inside terminal/. Enter listing 65, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_age.csv'
set terminal svg size 120,24
set output 'figures/by_age_people_sparkline.svg'
load 'style.gp'
unset border; unset tics; unset key; unset grid
set margins 0, 0, 0, 0
set yrange [0:*]
set offsets 0.5, 0.5, 0, 0
set boxwidth 0.7
set style fill solid 1.0 noborder
plot data using 0:2 with boxes lc 1
unset output

Run listing 66 from Bash in terminal/.

gnuplot -d plots/by_age_counts.gp

The SVG is only 120 by 24 pixels. Removing axes, tics, legend and grid, and setting all margins to zero, leaves room for the data. set offsets preserves a little horizontal space so the end bars are not cut off. Pseudo-column 0 places the rows at positions 0, 1, 2, … because the age labels in the first column are text.

Practice this topic in Challenge 19: Make a tiny chart understandable.

The same age groups now show the survival percentage as a line—not the number of survivors. Keep set yrange [0:100] so the vertical scale remains comparable between survival sparklines. Without it, small differences could be stretched to the full height.

In your editor, create plots/by_age_survival_rate.gp inside terminal/. Enter listing 67, then save the file before running it.

# Generated from plots-with-roots.dtx; run from the terminal directory.
reset
set encoding utf8
set datafile separator ","
set datafile columnheaders
data = 'data/titanic_by_age.csv'
set terminal svg size 120,24
set output 'figures/by_age_survival_sparkline.svg'
load 'style.gp'
unset border; unset tics; unset key; unset grid
set margins 0, 0, 0, 0
set yrange [0:100]
set offsets 0.3, 0.3, 0, 0
plot data using 0:3 with lines lw 1.5 lc 1
unset output

Run listing 68 from Bash in terminal/.

gnuplot -d plots/by_age_survival_rate.gp

The supplied browser gallery displays the tiny SVGs at sparkline size. When placing them in another document, use a height close to its text line rather than stretching them to a full-width chart.

The highest published rate is 67.9% for ages 3–5, compared with 61.8% for ages 0–2. The three oldest groups have no recorded survivors, but their counts are small. The trend is not monotonic.

Practice this topic in Challenge 20: See what an automatic scale hides.

After working through every plot, rerun the complete sequence. Check that all eighteen figures are present, including the large age/class heatmap and four-panel age comparison. Revisit the data description and the interpretation whenever changing the dataset version.

A reproducible rerun should not depend on invisible settings from an earlier interactive session. Keep the published inputs, explicit plotting commands and shared style together.

After saving all eighteen plot files and style.gp, create all.gp directly inside terminal/. Listing 69 contains one load command per plot; it does not download data, calculate summaries or create missing scripts.

# Run from terminal/: gnuplot -d all.gp
load 'plots/by_class_aboard.gp'
load 'plots/by_class_survivors.gp'
load 'plots/by_class_counts.gp'
load 'plots/by_class_styled.gp'
load 'plots/by_class_shared.gp'
load 'plots/by_class_stacked.gp'
load 'plots/by_class_shares.gp'
load 'plots/by_class_survival_rate.gp'
load 'plots/by_class_and_sex.gp'
load 'plots/by_class_pie.gp'
load 'plots/by_class_and_sex_heatmap.gp'
load 'plots/by_age_and_class_heatmap.gp'
load 'plots/by_age_and_class_panels.gp'
load 'plots/by_class_sex_gap.gp'
load 'plots/by_class_profile.gp'
load 'plots/by_class_donut.gp'
load 'plots/by_age_counts.gp'
load 'plots/by_age_survival_rate.gp'

Run listing 70 only after every script and all five CSVs exist.

gnuplot -d all.gp

Open the SVGs and PNGs in figures/, or reload the supplied index.html gallery. If a script is missing, return to its topic and save it first.

For individual reruns from Bash, use listing 71.

gnuplot -d plots/by_class_survivors.gp
gnuplot -d plots/by_class_counts.gp
gnuplot -d plots/by_class_styled.gp
gnuplot -d plots/by_class_survival_rate.gp

At the gnuplot prompt, use listing 72 instead. load reads the saved file again; replot repeats the most recent plot command with the current settings. Save edits before loading a file.

gnuplot> load 'plots/by_class_survival_rate.gp'
gnuplot> # Edit the file in your editor, then load it again:
gnuplot> load 'plots/by_class_survival_rate.gp'
gnuplot> exit

Practice this topic in Challenge 21: Prove that an edit reaches the output.

Of the 2,207 people in the published class table, 711 survived—about one in three. Passenger survival rates were 62.0% in first class, 41.5% in second and 25.5% in third; Crew's rate was 23.7%.

Crew also has the largest death count, 679, followed by third class with 528. Together these groups account for most deaths. Compare the stacked counts with the rate bars: a large number of deaths and a low survival rate are related but different descriptions.

Within every class and crew group, women survived at a higher rate than men. Among passengers, women's rates were approximately 97%, 89% and 49% in first, second and third class. Men's rates were approximately 34%, 13% and 15%. Among crew, 20 of 23 women survived (87%), compared with 191 of 867 men (22%). Read the small female crew count alongside its rate.

The age heatmap, four panels and sparkline show age patterns at different levels of detail. Only the two unknown ages are excluded from age-based plots; the class and sex plots include all records. Empty groups are not zero survival.

These numbers describe who survived, not why. The selected columns do not record deck location, access to lifeboats, evacuation timing or individual decisions. Do not infer causal effects of age, class or sex from these plots. Consult the dataset provenance before treating the supplied records as a definitive historical reconstruction.

The reported values belong to the pinned release. A new dataset version requires reviewing this interpretation as well as rerunning the code.

Practice this topic in Challenge 22: Write a claim the figure supports.

Work through the same questions when a plot surprises you: is the input available, is it read correctly, are the selected columns appropriate, and have you rerun and reopened the right output?

Stay in terminal/; confirm that all five files are under data/ and the figures/ directory exists. Use comma separation and column headers after reset. The scripts write SVG or PNG rather than opening a plot window. Keep Bash commands and gnuplot statements in their respective contexts.

If a browser still shows an older result, reload after running the correct script. The only network step in the lesson is downloading the CSVs.

Practice this topic in Challenge 23: Catch a plausible but wrong plot.

• Philipp K. Janert, Gnuplot in Action, Second Edition (Manning, 2016). Optional book on plotting and understanding data.
• Org Babel gnuplot tutorial. Worked examples of plotting functions and named tables in Org; some setup and output advice is historical.
• Plotting tables with org-plot. Examples and options for #+PLOT: directives above Org tables.